Rules for integrands of the form  (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)

1.  ∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0

0:  ∫(((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  when  d2 e1+d1 e2==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  d2 e1+d1 e2==0, then (d1+e1 x) (d2+e2 x)==d1 d2+e1 e2 (x^2)

Rule: If  d2 e1+d1 e2==0 ∧ p∈ℤ, then

∫(((d1+e1 x))^p) (((d2+e2 x))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  ∫(((d1 d2+e1 e2 (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx

Program code:

Int[(d1_+e1_.*x_)^p_.*(d2_+e2_.*x_)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Int[(d1*d2+e1*e2*x^2)^p*(a+b*ArcCosh[c*x])^n,x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,n},x] && EqQ[d2*e1+d1*e2,0] && IntegerQ[p]

1.  ∫((((a+b ArcCosh[c x]))^n)/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0

x:  ∫((((a+b ArcCosh[c x]))^n)/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  (c^2) d+e==0, then (∂_x)(((Sqrt[1+c x]) (Sqrt[-1+c x]))/(Sqrt[d+e (x^2)]))==0

Basis: ((F[ArcCosh[c x]])/((Sqrt[1+c x]) (Sqrt[-1+c x])))==(1/c) Subst[F[x],x,ArcCosh[c x]] (∂_x)ArcCosh[c x]

Note: When n==1, this rule would result in a slightly less compact antiderivative since ∫(((a+b x))^n)dx returns a sum.

Rule: If  (c^2) d+e==0, then

∫((((a+b ArcCosh[c x]))^n)/(Sqrt[d+e (x^2)]))dx  ⟶  (((Sqrt[1+c x]) (Sqrt[-1+c x]))/(c (Sqrt[d+e (x^2)]))) Subst[∫(((a+b x))^n)dx,x,ArcCosh[c x]]

Program code:

(* Int[(a_.+b_.*ArcCosh[c_.*x_])^n_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  1/c*Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]/Sqrt[d+e*x^2]]*Subst[Int[(a+b*x)^n,x],x,ArcCosh[c*x]] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[c^2*d+e,0] *)

1:  ∫(1/((Sqrt[d+e (x^2)])(a+b ArcCosh[c x])))dx  when  (c^2) d+e==0

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  (c^2) d+e==0, then (∂_x)(((Sqrt[1+c x]) (Sqrt[-1+c x]))/(Sqrt[d+e (x^2)]))==0

Rule: If  (c^2) d+e==0, then

∫(1/((Sqrt[d+e (x^2)])(a+b ArcCosh[c x])))dx  ⟶  (((Sqrt[1+c x]) (Sqrt[-1+c x]))/(b c (Sqrt[d+e (x^2)]))) Log[a+b ArcCosh[c x]]

Program code:

Int[1/(Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcCosh[c_.*x_])),x_Symbol] :=
  1/(b*c)*Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]/Sqrt[d+e*x^2]]*Log[a+b*ArcCosh[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0]

Int[1/(Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]*(a_.+b_.*ArcCosh[c_.*x_])),x_Symbol] :=
  1/(b*c)*Simp[Sqrt[1+c*x]/Sqrt[d1+e1*x]]*Simp[Sqrt[-1+c*x]/Sqrt[d2+e2*x]]*Log[a+b*ArcCosh[c*x]] /;
FreeQ[{a,b,c,d1,e1,d2,e2},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2]

2:  ∫((((a+b ArcCosh[c x]))^n)/(Sqrt[d+e (x^2)]))dx  when  (c^2) d+e==0 ∧ n≠-1

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  (c^2) d+e==0, then (∂_x)(((Sqrt[1+c x]) (Sqrt[-1+c x]))/(Sqrt[d+e (x^2)]))==0

Rule: If  (c^2) d+e==0 ∧ n≠-1, then

∫((((a+b ArcCosh[c x]))^n)/(Sqrt[d+e (x^2)]))dx  ⟶  (((Sqrt[1+c x]) (Sqrt[-1+c x]))/(b c (n+1) (Sqrt[d+e (x^2)]))) (((a+b ArcCosh[c x]))^(n+1))

Program code:

Int[(a_.+b_.*ArcCosh[c_.*x_])^n_./Sqrt[d_+e_.*x_^2],x_Symbol] :=
  1/(b*c*(n+1))*Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]/Sqrt[d+e*x^2]]*(a+b*ArcCosh[c*x])^(n+1) /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[c^2*d+e,0] && NeQ[n,-1]

Int[(a_.+b_.*ArcCosh[c_.*x_])^n_./(Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]),x_Symbol] :=
  1/(b*c*(n+1))*Simp[Sqrt[1+c*x]/Sqrt[d1+e1*x]]*Simp[Sqrt[-1+c*x]/Sqrt[d2+e2*x]]*(a+b*ArcCosh[c*x])^(n+1) /;
FreeQ[{a,b,c,d1,e1,d2,e2,n},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && NeQ[n,-1]

2.  ∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0

1:  ∫(((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  when  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: (∂_x)(a+b ArcCosh[c x])==((b c)/((Sqrt[1+c x]) (Sqrt[-1+c x])))

Rule: If  (c^2) d+e==0 ∧ p∈(SuperPlus[ℤ]), let  u->∫(((d+e (x^2)))^p)dx, then

∫(((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  ⟶  u(a+b ArcCosh[c x])-b c∫(u/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^2)^p,x]},  
  Dist[a+b*ArcCosh[c*x],u,x] - b*c*Int[SimplifyIntegrand[u/(Sqrt[1+c*x]*Sqrt[-1+c*x]),x],x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[p,0]

2.  ∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ p>0

1:  ∫(Sqrt[d+e (x^2)]) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0

Derivation: Inverted integration by parts

Note: The piecewise constant factor in the second integral reduces the degree of  d in the resulting antiderivative.

Rule: If  (c^2) d+e==0 ∧ n>0, then

∫(Sqrt[d+e (x^2)]) (((a+b ArcCosh[c x]))^n)dx  ⟶  
((x (Sqrt[d+e (x^2)]) (((a+b ArcCosh[c x]))^n))/2)-
((b c n(Sqrt[d+e (x^2)]))/(2 (Sqrt[1+c x]) (Sqrt[-1+c x])))∫x (((a+b ArcCosh[c x]))^(n-1))dx-((Sqrt[d+e (x^2)])/(2 (Sqrt[1+c x]) (Sqrt[-1+c x])))∫ ((((a+b ArcCosh[c x]))^n)/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx

Program code:

Int[Sqrt[d_+e_.*x_^2]*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  x*Sqrt[d+e*x^2]*(a+b*ArcCosh[c*x])^n/2 - 
  b*c*n/2*Simp[Sqrt[d+e*x^2]/(Sqrt[1+c*x]*Sqrt[-1+c*x])]*Int[x*(a+b*ArcCosh[c*x])^(n-1),x] - 
  1/2*Simp[Sqrt[d+e*x^2]/(Sqrt[1+c*x]*Sqrt[-1+c*x])]*Int[(a+b*ArcCosh[c*x])^n/(Sqrt[1+c*x]*Sqrt[-1+c*x]),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[n,0]

Int[Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  x*Sqrt[d1+e1*x]*Sqrt[d2+e2*x]*(a+b*ArcCosh[c*x])^n/2 - 
  b*c*n/2*Simp[Sqrt[d1+e1*x]/Sqrt[1+c*x]]*Simp[Sqrt[d2+e2*x]/Sqrt[-1+c*x]]*
    Int[x*(a+b*ArcCosh[c*x])^(n-1),x] - 
  1/2*Simp[Sqrt[d1+e1*x]/Sqrt[1+c*x]]*Simp[Sqrt[d2+e2*x]/Sqrt[-1+c*x]]*
    Int[(a+b*ArcCosh[c*x])^n/(Sqrt[1+c*x]*Sqrt[-1+c*x]),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0]

2:  ∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ p>0

Derivation: Inverted integration by parts

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ p>0, then

∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  

((x (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n))/(2p+1))+
((2 d p)/(2p+1))∫(((d+e (x^2)))^(p-1)) (((a+b ArcCosh[c x]))^n)dx-
((b c n (((d+e (x^2)))^p))/((2p+1) (((1+c x))^p) (((-1+c x))^p)))∫x (((1+c x))^(p-(1/2))) (((-1+c x))^(p-(1/2))) (((a+b ArcCosh[c x]))^(n-1))dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  x*(d+e*x^2)^p*(a+b*ArcCosh[c*x])^n/(2*p+1) + 
  2*d*p/(2*p+1)*Int[(d+e*x^2)^(p-1)*(a+b*ArcCosh[c*x])^n,x] - 
  b*c*n/(2*p+1)*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[x*(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && GtQ[p,0]

Int[(d1_+e1_.*x_)^p_.*(d2_+e2_.*x_)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  x*(d1+e1*x)^p*(d2+e2*x)^p*(a+b*ArcCosh[c*x])^n/(2*p+1) + 
  2*d1*d2*p/(2*p+1)*Int[(d1+e1*x)^(p-1)*(d2+e2*x)^(p-1)*(a+b*ArcCosh[c*x])^n,x] - 
  b*c*n/(2*p+1)*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[x*(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0] && GtQ[p,0]

3.  ∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ p<-1

1:  ∫((((a+b ArcCosh[c x]))^n)/(((d+e (x^2)))^(3/2)))dx  when  (c^2) d+e==0 ∧ n>0

Derivation: Integration by parts and piecewise constant extraction

Basis: (1/(((d+e (x^2)))^(3/2)))==(∂_x)(x/(d (Sqrt[d+e (x^2)])))

Basis: (∂_x)(((a+b ArcCosh[c x]))^n)==((b c n (((a+b ArcCosh[c x]))^(n-1)))/((Sqrt[1+c x]) (Sqrt[-1+c x])))

Basis: If  (c^2) d+e==0, then (∂_x)(((Sqrt[1+c x]) (Sqrt[-1+c x]))/(Sqrt[d+e (x^2)]))==0

Rule: If  (c^2) d+e==0 ∧ n>0, then

∫((((a+b ArcCosh[c x]))^n)/(((d+e (x^2)))^(3/2)))dx
  ⟶  ((x (((a+b ArcCosh[c x]))^n))/(d (Sqrt[d+e (x^2)])))-((b c n)/d)∫((x (((a+b ArcCosh[c x]))^(n-1)))/((Sqrt[1+c x]) (Sqrt[-1+c x]) (Sqrt[d+e (x^2)])))dx
  ⟶  ((x (((a+b ArcCosh[c x]))^n))/(d (Sqrt[d+e (x^2)])))+((b c n (Sqrt[1+c x]) (Sqrt[-1+c x]))/(d (Sqrt[d+e (x^2)])))∫((x (((a+b ArcCosh[c x]))^(n-1)))/(1-(c^2) (x^2)))dx

Program code:

Int[(a_.+b_.*ArcCosh[c_.*x_])^n_./(d_+e_.*x_^2)^(3/2),x_Symbol] :=
  x*(a+b*ArcCosh[c*x])^n/(d*Sqrt[d+e*x^2]) + 
  b*c*n/d*Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]/Sqrt[d+e*x^2]]*Int[x*(a+b*ArcCosh[c*x])^(n-1)/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[n,0]

Int[(a_.+b_.*ArcCosh[c_.*x_])^n_./((d1_+e1_.*x_)^(3/2)*(d2_+e2_.*x_)^(3/2)),x_Symbol] :=
  x*(a+b*ArcCosh[c*x])^n/(d1*d2*Sqrt[d1+e1*x]*Sqrt[d2+e2*x]) + 
  b*c*n/(d1*d2)*Simp[Sqrt[1+c*x]/Sqrt[d1+e1*x]]*Simp[Sqrt[-1+c*x]/Sqrt[d2+e2*x]]*
    Int[x*(a+b*ArcCosh[c*x])^(n-1)/(1-c^2*x^2),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0]

2:  ∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n>0 ∧ p<-1 ∧ p≠-(3/2)

Rule: If  (c^2) d+e==0 ∧ n>0 ∧ p<-1 ∧ p≠-(3/2), then

∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  

-((x (((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n))/(2 d (p+1)))+
((2 p+3)/(2 d (p+1)))∫(((d+e (x^2)))^(p+1)) (((a+b ArcCosh[c x]))^n)dx-
((b c n (((d+e (x^2)))^p) )/(2 (p+1) (((1+c x))^p) (((-1+c x))^p)))∫x (((1+c x))^(p+(1/2))) (((-1+c x))^(p+(1/2))) (((a+b ArcCosh[c x]))^(n-1))dx

Program code:

Int[(d_+e_.*x_^2)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  -x*(d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])^n/(2*d*(p+1)) + 
  (2*p+3)/(2*d*(p+1))*Int[(d+e*x^2)^(p+1)*(a+b*ArcCosh[c*x])^n,x] - 
  b*c*n/(2*(p+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[x*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && GtQ[n,0] && LtQ[p,-1] && NeQ[p,-3/2]

Int[(d1_+e1_.*x_)^p_*(d2_+e2_.*x_)^p_*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  -x*(d1+e1*x)^(p+1)*(d2+e2*x)^(p+1)*(a+b*ArcCosh[c*x])^n/(2*d1*d2*(p+1)) + 
  (2*p+3)/(2*d1*d2*(p+1))*Int[(d1+e1*x)^(p+1)*(d2+e2*x)^(p+1)*(a+b*ArcCosh[c*x])^n,x] - 
  b*c*n/(2*(p+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[x*(1+c*x)^(p+1/2)*(-1+c*x)^(p+1/2)*(a+b*ArcCosh[c*x])^(n-1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && GtQ[n,0] && LtQ[p,-1] && NeQ[p,-3/2]

4:  ∫((((a+b ArcCosh[c x]))^n)/(d+e (x^2)))dx  when  (c^2) d+e==0 ∧ n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: If  (c^2) d+e==0, then (1/(d+e (x^2)))==(1/(c d)) Subst[Sech[x],x,ArcCosh[c x]] (∂_x)ArcCosh[c x]

Note: If  n∈(SuperPlus[ℤ]), then (((a+b x))^n) Sech[x] is integrable in closed-form.

Rule: If  (c^2) d+e==0 ∧ n∈(SuperPlus[ℤ]), then

∫((((a+b ArcCosh[c x]))^n)/(d+e (x^2)))dx  ⟶  (1/(c d))Subst[∫(((a+b x))^n) Sech[x]dx,x,ArcCosh[c x]]

Program code:

Int[(a_.+b_.*ArcCosh[c_.*x_])^n_./(d_+e_.*x_^2),x_Symbol] :=
  -1/(c*d)*Subst[Int[(a+b*x)^n*Csch[x],x],x,ArcCosh[c*x]] /;
FreeQ[{a,b,c,d,e},x] && EqQ[c^2*d+e,0] && IGtQ[n,0]

3:  ∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ n<-1

Derivation: Integration by parts and piecewise constant extraction

Basis: ((((a+b ArcCosh[c x]))^n)/((Sqrt[1+c x]) (Sqrt[-1+c x])))==(∂_x)((((a+b ArcCosh[c x]))^(n+1))/(b c (n+1)))

Basis: If  (c^2) d+e==0, then (∂_x)((Sqrt[1+c x]) (Sqrt[-1+c x]) (((d+e (x^2)))^p))==(((c^2) (2 p+1) x (((d+e (x^2)))^p))/((Sqrt[1+c x]) (Sqrt[-1+c x])))

Basis: If  (c^2) d+e==0, then (∂_x)((((d+e (x^2)))^p)/((((1+c x))^p) (((-1+c x))^p)))==0

Basis: If  p+(1/2)∈ℤ, then (((1+c x))^(p-(1/2))) (((-1+c x))^(p-(1/2)))==(((-1+(c^2) (x^2)))^(p-(1/2)))

Rule: If  (c^2) d+e==0 ∧ n<-1, then

∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx

  ⟶  (((Sqrt[1+c x]) (Sqrt[-1+c x]) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^(n+1)))/(b c(n+1)))-
((c(2 p+1))/(b(n+1)))∫((x (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^(n+1)))/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx

  ⟶  (((Sqrt[1+c x]) (Sqrt[-1+c x]) (((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^(n+1)))/(b c(n+1)))-
((c(2 p+1) (((d+e (x^2)))^p))/(b(n+1) (((1+c x))^p) (((-1+c x))^p)))∫x (((1+c x))^(p-(1/2))) (((-1+c x))^(p-(1/2))) (((a+b ArcCosh[c x]))^(n+1))dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  Simp[Sqrt[1+c*x]*Sqrt[-1+c*x]*(d+e*x^2)^p]*(a+b*ArcCosh[c*x])^(n+1)/(b*c*(n+1)) - 
  c*(2*p+1)/(b*(n+1))*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*
    Int[x*(1+c*x)^(p-1/2)*(-1+c*x)^(p-1/2)*(a+b*ArcCosh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d,e,p},x] && EqQ[c^2*d+e,0] && LtQ[n,-1] && IntegerQ[2*p]

Int[(d1_+e1_.*x_)^p_.*(d2_+e2_.*x_)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  Sqrt[1+c*x]*Sqrt[-1+c*x]*(d1+e1*x)^p*(d2+e2*x)^p*(a+b*ArcCosh[c*x])^(n+1)/(b*c*(n+1)) - 
  c*(2*p+1)/(b*(n+1))*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*
    Int[x*(-1+c^2*x^2)^(p-1/2)*(a+b*ArcCosh[c*x])^(n+1),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,p},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && LtQ[n,-1] && IntegerQ[p+1/2]

4:  ∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e==0 ∧ 2 p∈(SuperPlus[ℤ])

Derivation: Piecewise constant extraction and integration by substitution

Basis: If  (c^2) d+e==0, then (∂_x)((((d+e (x^2)))^p)/((((1+c x))^p) (((-1+c x))^p)))==0

Basis: If  2p∈ℤ, then (((1+c x))^p) (((-1+c x))^p)==(1/(b c)) Subst[((Sinh[-(a/b)+(x/b)])^(2p+1)),x,a+b ArcCosh[c x]] (∂_x)(a+b ArcCosh[c x])

Note: If  2 p∈(SuperPlus[ℤ]), then (x^n) ((Sinh[-(a/b)+(x/b)])^(2p+1)) is integrable in closed-form.

Rule: If  (c^2) d+e==0 ∧ 2 p∈(SuperPlus[ℤ]), then

∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx

  ⟶  ((((d+e (x^2)))^p)/((((1+c x))^p) (((-1+c x))^p))) ∫(((1+c x))^p) (((-1+c x))^p) (((a+b ArcCosh[c x]))^n)dx

  ⟶  ((((d+e (x^2)))^p)/(b c (((1+c x))^p) (((-1+c x))^p))) Subst[∫(x^n) ((Sinh[-(a/b)+(x/b)])^(2p+1))dx,x,a+b ArcCosh[c x]]

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  1/(b*c)*Simp[(d+e*x^2)^p/((1+c*x)^p*(-1+c*x)^p)]*Subst[Int[x^n*Sinh[-a/b+x/b]^(2*p+1),x],x,a+b*ArcCosh[c*x]] /;
FreeQ[{a,b,c,d,e,n},x] && EqQ[c^2*d+e,0] && IGtQ[2*p,0]

Int[(d1_+e1_.*x_)^p_.*(d2_+e2_.*x_)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  1/(b*c)*Simp[(d1+e1*x)^p/(1+c*x)^p]*Simp[(d2+e2*x)^p/(-1+c*x)^p]*Subst[Int[x^n*Sinh[-a/b+x/b]^(2*p+1),x],x,a+b*ArcCosh[c*x]] /;
FreeQ[{a,b,c,d1,e1,d2,e2,n},x] && EqQ[e1,c*d1] && EqQ[e2,-c*d2] && IGtQ[2*p,0]

2.  ∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e≠0

1:  ∫(((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  when  (c^2) d+e≠0 ∧ (p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ]))

Derivation: Integration by parts

Basis: (∂_x)(a+b ArcCosh[c x])==((b c)/((Sqrt[1+c x]) (Sqrt[-1+c x])))

Note: If  p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ]), then ∫(((d+e (x^2)))^p)dx is a rational function.

Rule: If  (c^2) d+e≠0 ∧ (p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ])), let  u->∫(((d+e (x^2)))^p)dx, then

∫(((d+e (x^2)))^p) (a+b ArcCosh[c x])dx  ⟶  u(a+b ArcCosh[c x])-b c∫(u/((Sqrt[1+c x]) (Sqrt[-1+c x])))dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^2)^p,x]},  
  Dist[a+b*ArcCosh[c*x],u,x] - b*c*Int[SimplifyIntegrand[u/(Sqrt[1+c*x]*Sqrt[-1+c*x]),x],x]] /;
FreeQ[{a,b,c,d,e},x] && NeQ[c^2*d+e,0] && (IGtQ[p,0] || ILtQ[p+1/2,0])

x:  ∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  p∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: F[x]==(1/(b c)) Subst[F[((Cosh[-(a/b)+(x/b)])/c)] Sinh[-(a/b)+(x/b)],x,a+b ArcCosh[c x]] (∂_x)(a+b ArcCosh[c x])

Note: If  p∈(SuperPlus[ℤ]), then (x^n) ((((c^2) d+e ((Cosh[-(a/b)+(x/b)])^2)))^p) Sinh[-(a/b)+(x/b)] is integrable in closed-form.

Rule: If  p∈(SuperPlus[ℤ]), then

∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  (1/(b (c^(2 p+1)))) Subst[∫(x^n) ((((c^2) d+e ((Cosh[-(a/b)+(x/b)])^2)))^p) Sinh[-(a/b)+(x/b)]dx,x,a+b ArcCosh[c x]]

Program code:

(* Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_,x_Symbol] :=
  1/(b*c^(2*p+1))*Subst[Int[x^n*(c^2*d+e*Cosh[-a/b+x/b]^2)^p*Sinh[-a/b+x/b],x],x,a+b*ArcCosh[c*x]] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[p,0] *)

3:  ∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  when  (c^2) d+e≠0 ∧ p∈ℤ ∧ (p>0 ∨ n∈(SuperPlus[ℤ]))

Derivation: Algebraic expansion

Rule: If  (c^2) d+e≠0 ∧ p∈ℤ ∧ (p>0 ∨ n∈(SuperPlus[ℤ])), then

∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  ∫ (((a+b ArcCosh[c x]))^n) ExpandIntegrand[(((d+e (x^2)))^p),x]dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*ArcCosh[c*x])^n,(d+e*x^2)^p,x],x] /;
FreeQ[{a,b,c,d,e,n},x] && NeQ[c^2*d+e,0] && IntegerQ[p] && (p>0 || IGtQ[n,0])

U:  ∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx

Rule:

∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx  ⟶  ∫(((d+e (x^2)))^p) (((a+b ArcCosh[c x]))^n)dx

Program code:

Int[(d_+e_.*x_^2)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[(d+e*x^2)^p*(a+b*ArcCosh[c*x])^n,x] /;
FreeQ[{a,b,c,d,e,n,p},x]

Int[(d1_+e1_.*x_)^p_.*(d2_+e2_.*x_)^p_.*(a_.+b_.*ArcCosh[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[(d1+e1*x)^p*(d2+e2*x)^p*(a+b*ArcCosh[c*x])^n,x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,n,p},x]